ClearAll["Global`*"]

Kerr geometry and geodesics

Author: Tangchao Liu
Time: December 2024
Email: tangchaoliu4@gmail.com

This notebook mainly aims to solve problem 4 of chapter 5 of the book << A Relativist’s Toolkit:  the mathematics of black hole mechanics>> (called the toolkit book henceforth) by Eric Poisson, about Kerr geodesics. A few formulae in the text of chapter 5 are also verified to ensure the validity of the codes. The 4-velocity components in Boyer-Lindquist coordinate are given in closed forms.

The metric signature is (-+++) as in the book, but the tensor indices are lower case Latin indices. Confusion is not likely since this notebook does not deal with hypersurface geometry as in chapter 3 of the toolkit book.

<<xAct`xTensor`
<<xAct`xCoba`

DefManifold[M,4,{a,b,c,d,e,f,g,h,i,j,p,q}]

Boyer-Lindquist coordinate

First the metric in the Boyer-Lindquist (BL) coordinate should be set up, as well as the structures associated with it, such as covariant derivatives.

Define the chart.

DefChart[BL,M,{0,1,2,3},{t[],r[],θ[],ϕ[]},ChartColor->Blue]

Define the Kerr parameters and the  that appear in the metric.

DefConstantSymbol[mass,PrintAs->"M"];
DefConstantSymbol[spin,PrintAs->"a"];
ρ= Sqrt[((r[])^2)+spin^2 ((Cos[θ[]])^2)];
Δ=((r[])^2)-2mass r[]+(spin^2);
Σ=(((((r[])^2)+(spin^2)))^2)-(spin^2) Δ ((Sin[θ[]])^2);

Define the metric as a CTensor object.

$Assumptions=mass>0&&0<Abs[spin]<mass&& 0<θ[]<π && 0<ϕ[]<2π && t[]∈ Reals;

g=CTensor[
{{-1+((2 mass r[])/(ρ^2)),0,0,-((2 mass spin r[] ((Sin[θ[]])^2))/(ρ^2))},{0,((ρ^2)/Δ),0,0},{0,0,(ρ^2),0},{-((2 mass spin r[] ((Sin[θ[]])^2))/(ρ^2)),0,0,(Σ/(ρ^2))((Sin[θ[]])^2)}},
{-BL,-BL}];
SetCMetric[g,BL,SignatureOfMetric->{3,1,0}]

Visualize the metric components as matrices.

g[-a,-b]
g[a,b]

Eq (5.46) in the toolkit book also gives the components of the inverse metric. We can use it to verify that the codes above are correct.

FullSimplify[g[{0,BL},{0,BL}]+(Σ/((ρ^2)Δ))]
FullSimplify[g[{0,BL},{3,BL}]+((2 mass spin r[])/((ρ^2)Δ))]
FullSimplify[g[{3,BL},{3,BL}]-((Δ-(spin^2)((Sin[θ[]])^2))/((ρ^2)Δ ((Sin[θ[]])^2)))]
FullSimplify[g[{1,BL},{1,BL}]-(Δ/(ρ^2))]
FullSimplify[g[{2,BL},{2,BL}]-(1/(ρ^2))]

The metric is indeed the same as the one in the book. The next thing we can cross-check is the Kretchmann scalar and the fact that the metric indeed satisfies vacuum Einstein equation.

cd=CovDOfMetric[g];

Ricci[cd][-a,-b]

Vacuum Einstein equation is satisfied. Now the Kretchmann scalar.

FullSimplify[Sum[Riemann[cd][{a,-BL},{b,-BL},{c,-BL},{d,-BL}]Riemann[cd][{a,BL},{b,BL},{c,BL},{d,BL}],
{a,0,3},{b,0,3},{c,0,3},{d,0,3}]]

Although it doesn’t quite look the same as (5.47) in the toolkit book, but their difference

FullSimplify[
((48 (mass^2) (((r[])^2)-(spin^2) ((Cos[θ[]])^2))((ρ^4)-16 (spin^2) ((r[])^2) ((Cos[θ[]])^2)))/(ρ^12))-Sum[Riemann[cd][{a,-BL},{b,-BL},{c,-BL},{d,-BL}]Riemann[cd][{a,BL},{b,BL},{c,BL},{d,BL}],
{a,0,3},{b,0,3},{c,0,3},{d,0,3}]
]

is indeed 0.

Principle null congruence and Kerr geodesics

Problem 4(a)

(a)Show that if  is a Killing tensor satisfying  then  is a constant of motion given is the tangent vector of an affinely parametrized geodesic, i.e., .

Just use definition
.
This is directly the consequence of  and .

Examination of principle null congruences and Problem(4b)

(b) Verify that in Kerr, is a Killing tensor, with and given by (5.59) and (5.60) in the book as principle null congruences.

l=CTensor[{((((r[])^2)+(spin^2))/Δ),-1,0,(spin/Δ)},{BL}];
k=CTensor[{((((r[])^2)+(spin^2))/Δ),1,0,(spin/Δ)},{BL}];

Check that they are null and geodesics

(*The norm should be 0 if they are null*)
FullSimplify[l[a]l[-a]]
FullSimplify[k[a]k[-a]]
(*The following should also be 0 if they are affinely parametrized geodesics*)
FullSimplify[l[a]cd[-a]@l[b]]
FullSimplify[k[a]cd[-a]@k[b]]

FullSimplify[l[-a]k[a]-((-2(ρ^2))/Δ)]

This should imply that if we rescale the outgoing principle null congruence by , it should satisfy , where .

n=CTensor[{((((r[])^2)+(spin^2))/(2 (ρ^2))),(Δ/(2 (ρ^2))),0,(spin/(2 (ρ^2)))},{BL}];
FullSimplify[l[-a]n[a]]
FullSimplify[n[a]n[-a]]
FullSimplify[n[a]cd[-a]@n[b]]

is still null, and have inner product -1 with . We know that Kerr is a Petrov type D spacetime. These two principle null congruences, by Goldberg-Sachs theorem, should have no expansion and shear. We can try to verify this.

Section 2.4 of the toolkit book on null congruence gives a prescription of computing these. Take the null geodesic congruence for example. The expansion is

and the shear is

where the projector is
.

hNS=CTensor[FullSimplify[
Table[g[{a,-BL},{b,-BL}]+l[{a,-BL}]n[{b,-BL}]+n[{a,-BL}]l[{b,-BL}],{a,0,3},{b,0,3}]
],{-BL,-BL}];

(*Expansion for l congruence*)
expnl=FullSimplify[g[a,b](cd[-b]@l[-a])]
(*Shear for l congruence*)
shearl=FullSimplify[cd[-b]@l[-a]-(1/2)expnl hNS[-a,-b]]

They are not zero. Maybe my understanding of Goldberg-Sachs theorem is not correct. It might be more complicated than this. I have to check the literature. And the above treatment for  congruence should be modified, according to problem 8 of section 2.5 of the toolkit book, since it’s not affinely parametrized. This calculation should be resumed once a correct understanding of Goldberg-Sachs theorem is at hand.

Now just check  in BL coordinate. The only way for coding this I know is

cd[-c][(Δ/2)(l[-a]k[-b]+l[-b]k[-a])+((r[])^2)g[-a,-b]]+cd[-a][(Δ/2)(l[-b]k[-c]+l[-c]k[-b])+((r[])^2)g[-b,-c]]+cd[-b][(Δ/2)(l[-c]k[-a]+l[-a]k[-c])+((r[])^2)g[-c,-a]]+cd[-a][(Δ/2)(l[-c]k[-b]+l[-b]k[-c])+((r[])^2)g[-c,-b]]+cd[-b][(Δ/2)(l[-a]k[-c]+l[-c]k[-a])+((r[])^2)g[-a,-c]]+cd[-c][(Δ/2)(l[-b]k[-a]+l[-a]k[-b])+((r[])^2)g[-b,-a]]

But for the moment I don’t know how to symmetrize the indices in xTensor and xCoba without doing it manually. I can naively try the following

sometensor=l[-a]k[-b]
ξ=Δ Symmetrize[sometensor]+((r[])^2)g[-a,-b]

What I want to symmetrize is

cd[-c]@ξ[-a,-b]

The problem is, it’s giving me a vector, not a rank 3 tensor. And also, since the command Symmetrize above appears in more than one context, one is shadowed. I don’t know what exactly is going on inside the package. I certainly don’t want to manually symmetrize or anti-symmetrize when there are too many indices.

Problem 4(c)

(c)Now let’s solve for  and  for the 4-velocity of the geodesic .

(*Definet the 4-velocity*)
u=CTensor[{u0,u1,u2,u3},{BL}]
(*Define the 2 constants of motion with no tilde notation*)
DefConstantSymbol[EperPar,PrintAs->"E"]
DefConstantSymbol[AMperPar,PrintAs->"L"]

A=(({{g[{0,BL},{0,BL}], g[{3,BL},{0,BL}]}, {g[{0,BL},{1,BL}], g[{3,BL},{1,BL}]}, {g[{0,BL},{2,BL}], g[{3,BL},{2,BL}]}, {g[{0,BL},{3,BL}], g[{3,BL},{3,BL}]}})).(({{-EperPar}, {AMperPar}}));
B=(({{g[{0,BL},{0,BL}], g[{3,BL},{0,BL}]}, {g[{0,BL},{1,BL}], g[{3,BL},{1,BL}]}, {g[{0,BL},{2,BL}], g[{3,BL},{2,BL}]}, {g[{0,BL},{3,BL}], g[{3,BL},{3,BL}]}})).(({{g[{0,-BL},{0,-BL}], g[{0,-BL},{1,-BL}], g[{0,-BL},{2,-BL}], g[{0,-BL},{3,-BL}]}, {g[{3,-BL},{0,-BL}], g[{3,-BL},{1,-BL}], g[{3,-BL},{2,-BL}], g[{3,-BL},{3,-BL}]}}));

In this calculation, one is tempted to evaluate
(({{u[{0,BL}]}, {u[{1,BL}]}, {u[{2,BL}]}, {u[{3,BL}]}}))==Inverse[B].A
but this cannot work since B is degenerate.

FullSimplify[B]//MatrixForm

This makes sense since there are just 2 conditions, certainly not enough to determine 4 unknowns. But this also tells us that  and  are just the first and last component of the vector A, giving us the solution to 4(c).

KnowledgeOnU0=u0->A[[1]];
KnowledgeOnU3=u3->A[[4]];
FullSimplify[KnowledgeOnU0]
FullSimplify[KnowledgeOnU3]

This result is independent of whether the geodesic is timelike or null, and remains to be checked with the last equations in page 192 of the toolkit book.

Problem 4(d)

(d)Now we know  is a constant of motion. Define the Carter constant as
.
Calculate the left hand side to give .

This one is actually easier to do by hand. 
,
where  as given in problem 4(e). It’s 0 for null and 1 for timelike geodesic. 
,
,
.
Continue the previous calculation
,
where , so

In terms of codes, we can write down the following

DefConstantSymbol[Carter,PrintAs->"C"]
F=(spin/Δ)AMperPar-((((r[])^2)+(spin^2))/Δ)EperPar;
rDotSquare=((g[{1,-BL},{1,-BL}])^(-2))((F^2)-((Carter+(((AMperPar-spin EperPar))^2)+ζ ((r[])^2))/Δ));
uTimelike=ζ->1;
uNull=ζ->0;

Now we have an expression for , hence the solution to problem 4(d).

KnowledgeOnU1=u1->Sqrt[rDotSquare];
(*rdot for timelike geodesic*)
FullSimplify[KnowledgeOnU1]/.uTimelike
(*rdot for null geodesic*)
FullSimplify[KnowledgeOnU1]/.uNull

Problem 4(e)

(e) With  determined as above, use the final condition, the normalization  to determine the last unknown , with =0 for null and =1 for timelike geodesics.

solnU2=Solve[g[-a,-b]u[a]u[b]==-ζ,u2];
FullSimplify[solnU2]

ρ^2
Δ

The two solutions simply correspond to moving towards the north and south pole. The condition for these solutions to hold mean that the particle must neither be at the singularity  nor at the horizons . Now we further specify  with knowledge of the other components.

solnU2WithOtherU=FullSimplify[
solnU2/.{KnowledgeOnU0,KnowledgeOnU1,KnowledgeOnU3}
]

Let’s explicitly see it with timelike and null geodesics respectively.

solnU2WithOtherU[[2]]/.uTimelike
solnU2WithOtherU[[2]]/.uNull

Summary and cross-check

The components for timelike and null geodesics in Kerr in BL coordinate

(*Timelike*)
FullSimplify[KnowledgeOnU0]
FullSimplify[KnowledgeOnU1/.uTimelike]
FullSimplify[solnU2WithOtherU[[2]]]/.uTimelike
FullSimplify[KnowledgeOnU3]

(*Null*)
FullSimplify[KnowledgeOnU0]
FullSimplify[KnowledgeOnU1/.uNull]
FullSimplify[solnU2WithOtherU[[2]]]/.uNull
FullSimplify[KnowledgeOnU3]

For the null case, we can check whether it coincides with the expressions given in page 192 of the toolkit book.

From now on, add the assumptions that we are neither at the singularity nor at the horizons.

$Assumptions=mass>0&&0<Abs[spin]<mass&& 0<θ[]<π && 0<ϕ[]<2π && t[]∈ Reals&&((a^2) ((Cos[θ])^2)+(r^2)) ((a^2)-2 M r+(r^2))!=0;

(*Null*)
FullSimplify[KnowledgeOnU0]
FullSimplify[KnowledgeOnU1/.uNull]
FullSimplify[solnU2WithOtherU[[2]]]/.uNull
FullSimplify[KnowledgeOnU3]

Define the 4-velocity of null geodesics given by page 192 of the toolkit book by .

v=CTensor[{v0,v1,v2,v3},{BL}];
(*The functions P, R, Θ at page 193*)
P=EperPar(((r[])^2)+(spin^2))-spin AMperPar;
R=(P^2)-Δ((((AMperPar-spin EperPar))^2)+Carter);
Θ=Carter+((Cos[θ[]])^2)((spin^2) (EperPar^2)-((AMperPar^2)/((Sin[θ[]])^2)));

Now we simply compute the  components of  and compare it with those of .

v0=(ρ^(-2))(-spin*( spin*EperPar*((Sin[θ[]])^2) - AMperPar )+(P/Δ)(((r[])^2)+(spin^2)));
v1=(ρ^(-2))Sqrt[R];
v2=(ρ^(-2))Sqrt[Θ];
v3=(ρ^(-2))(-( spin*EperPar- AMperPar/((Sin[θ[]])^2)  )+((spin*P)/Δ));

FullSimplify[v0-u0/.KnowledgeOnU0]
FullSimplify[v3-u3/.KnowledgeOnU3]

FullSimplify[v1-u1/.KnowledgeOnU1/.uNull]
FullSimplify[(v1^2)-(u1^2)/.KnowledgeOnU1/.uNull]

FullSimplify[(v2^2)-(u2^2)/.solnU2WithOtherU[[2]]/.uNull]

The cross-checking for the null geodesics in Kerr in BL coordinate is completed. It is assumed that the results for timelike geodesic computed in this notebook should also be correct. Of course, it remains to discuss the physical interpretation and visualization of these analytic results.