Chapter 2. Congruences

Author: Tangchao Liu
Time: August 2024
Email: tangchaoliu4@gmail.com

This notebook is dedicated to the problems of chapter 2 of Eric Poisson’s book, a relativist’s toolkit: the mathematical theory of black-hole mechanics.

Clear["Global`*"]

2. FLRW spacetime

This problem explores the expansion, shear and rotation of the FLRW spacetime, with the metric given by the line element
.                        (1)                                         
The congruence under examination is the one with tangent vectors . Before calculating, one might expect the expansion, shear and rotation to be 
 for a homogeneous and isotropic spacetime. Let’s verify if this is true.

2.(a) Verify that  indeed is the tangent vector of a geodesic.

(*Specify coordinates and dimension*)
coord={t,r,θ,ϕ}
n=Length[coord]

(*specify the metric*)
g=(({{-1, 0, 0, 0}, {0, (((a[t])^2)/(1-κ (r^2))), 0, 0}, {0, 0, ((a[t])^2)(r^2), 0}, {0, 0, 0, ((a[t])^2)(r^2)((Sin[θ])^2)}}));
ginv=Inverse[g];
g//MatrixForm
ginv//MatrixForm

(*Use MaTeX to display the formulae better*)
<<MaTeX`

MaTeX[g//MatrixForm]
MaTeX[ginv//MatrixForm]

Then we can start computing the Christoffel symbols
 ,                                      (2)
i.e., the affine connection coefficients associated to the Levi-Civita connection. Call it affine as variable name.

affine:=affine=FullSimplify[
Table[
(1/2)*
Sum[ginv[[i,s]]*(D[g[[s,k]],coord[[j]]]+D[g[[s,j]],coord[[k]]]-D[g[[j,k]],coord[[s]]]),{s,1,n}],
{i,1,n},{j,1,n},{k,1,n}]
];

(*Display the non-zero Christoffel symbols*)
NonZeroAffineList:=Table[
If[UnsameQ[affine[[i,j,k]],0],
{Subscript[Superscript[Γ,coord[[i]]],Row[{coord[[j]],coord[[k]]}]],affine[[i,j,k]]}(*It returns a pair: the symbol and the value*)
],
{i,1,n},{j,1,n},{k,1,j}]
Partition[DeleteCases[Flatten[NonZeroAffineList],Null],2]//TableForm

Now we want to check the geodesic equation
.                                                   (3)
In this coordinate , so the first term, the acceleration term identically vanishes. And only the term  gives non-trivial contribution (here the index goes from 1 to 4).

affine[[1]]//MatrixForm

affine[1,1,1] = 0, so it’s verified that for , the right hand side vanishes. Actually from the table above it’s obvious that

affine[[2,1,1]]
affine[[3,1,1]]
affine[[4,1,1]]

So the geodesic equation is verified, and it’s in the affine form. In fact, our discussions in the main text all rely on the assumption of affine parametrization.

2.(b) Compute the expansion, shear and rotation of this timelike congruence.

The formulas for the quantities are, in this particular frame
                                                               (4)
, obviously the rotation . And
, where .

(*The 4-velocity and transverse matrix in this frame*)
u={1,0,0,0}
uCov=g.u (*The 1-form u*)
h=g+Outer[Times,uCov,uCov];(*Don't use MatrixForm when doing computations*)
hinv=ginv+Outer[Times,u,u];
h//MatrixForm
hinv//MatrixForm

MaTeX[h.hinv//MatrixForm]

(*The (0,2) tensor B in this frame*)
B=affine[[1]];
(*Again don't use MatrixForm when evaluating things*)
MaTeX[B//MatrixForm]

(*Take the trace of B with hinv*)
expansion=Tr[hinv.B]

shear=B-(1/3)*expansion *h;
shear//MatrixForm

We have our answers , as guessed before. We can verify the result for the expansion via equation (4) given above.

expansion2=Sum[affine[[i,j,1]],{i,n},{j,n}]
expansion2==expansion

2.(c) Use Raychaudhuri’s equation to derive Friedmann equation

The Raychaudhuri’s equation for timelike geodesic congruence is
.                                 (5)
Apply Einstein field equation to the Ricci tensor term, with the energy momentum tensor being that of a perfect fluid
,                                                            (6)
we get
.                                                         (7)
The shear and rotation are computed as 0, so the Raychaudhuri’s equation becomes
.                                                       (8)
With the result , we easily get
.                                                                (9)

Extra: derive the first Friedmann equation from Einstein equation.

Actually we have implicitly implemented a (3+1) split, that is, a foliation. The second Friedmann equation (9) is the evolution equation. And the first Friedmann equation should be the energy constraint. The momentum constraint is satisfied by a trivial identity . Let’s compute the Einstein tensor in this coordinate and compare it with the perfect fluid stress energy momentum (SEM) tensor.

(*The (0,2) covariant SEM tensor*)
T=(ρ+p)Outer[Times,uCov,uCov]+p g;
T//MatrixForm

The Riemann tensor

riemann:=riemann=FullSimplify[Table[
D[ affine[[i,l,j]],coord[[k]] ]-D[ affine[[i,k,j]],coord[[l]] ]+Sum[affine[[i,k,m]]affine[[m,l,j]]-affine[[i,l,m]]affine[[m,k,j]],{m,1,n}],
{i,1,n},{j,1,n},{k,1,n},{l,1,n}
]
]

The covariant Riemann , the Ricci , and the Einstein tensor

riemann04:=riemann04=FullSimplify[
Table[
Sum[g[[i,s]]riemann[[s,j,k,l]],{s,1,n}],
{i,1,n},{j,1,n},{k,1,n},{l,1,n}
]
];
ricci02:=ricci02=FullSimplify[
Table[
Sum[ginv[[k,l]]riemann04[[i,k,j,l]],{k,1,n},{l,1,n}],{i,1,n},{j,1,n}
]
];
RicciScalar=Sum[ginv[[i,j]]ricci02[[i,j]],{i,n},{j,n}];
einstein02:=einstein02=FullSimplify[
Table[
ricci02[[i,j]]-1/2*RicciScalar*g[[i,j]],{i,1,n},{j,1,n}
]
];

MaTeX[8π T//MatrixForm]
MaTeX[einstein02//MatrixForm]

The 00 component clearly says
.                                                             (10)
This is indeed the first Friedmann equation.